SubversionBackup

UserPreferences

1. Full Backup
1. svnadmin hotcopy
2. svnadmin dump
2. Incremental Backup

1 Full Backup

1.1 svnadmin hotcopy

문법


svnadmin hotcopy OLD_REPOS_PATH NEW_REPOS_PATH [--clean-logs] 

샘플 배치 파일


@echo off 
 
rem 백업할 저장소의 위치 
SET REPOSITORY=D:\SVN\Cuvit 
 
rem 임시로 사용할 저장소의 이름 
SET TEMP_REPOSITORY=D:\SVN\CuvitBackup 
 
rem 백업 파일 앞에다 붙일 경로 
SET BACKUP_FILE_PREFIX=D:\ 
 
rem 백업 파일 뒤에다 붙일 이름 
SET BACKUP_FILE_POSTFIX=CUVIT_SVN 
 
 
rem 타이틀 표시 
@TITLE Backing up subversion databases 
 
rem 백업 파일 이름의 일부로 사용할 문자열 생성 
FOR /F "tokens=1-3 delims=- " %%i IN ('date /t') DO SET DATE=%%i-%%j-%%k 
 
rem 핫카피를 만든다. 
svnadmin hotcopy "%REPOSITORY%" "%TEMP_REPOSITORY%" --clean-logs 
 
rem 압축한다 
SET BACKUP_FILE=%BACKUP_FILE_PREFIX%%DATE%%BACKUP_FILE_POSTFIX%.rar 
"C:\Program Files\WinRAR\rar" a -m5 "%BACKUP_FILE%" "%TEMP_REPOSITORY%" 
 
rem 핫카피를 삭제 
rmdir "%TEMP_REPOSITORY%" /s /q 

hotcopy를 이용한 경우에는 되돌리려면 그냥 적당한 위치에 복사만 하면 된다.



1.2 svnadmin dump

문법


svnadmin dump REPOS_PATH [-r LOWER[:UPPER]] [--incremental] 

샘플 배치 파일


@echo off 
 
rem 백업할 저장소의 위치 
SET REPOSITORY=D:\SVN\Cuvit 
 
rem 백업 파일 앞에다 붙일 경로 
SET BACKUP_FILE_PREFIX=D:\ 
 
rem 백업 파일 뒤에다 붙일 이름 
SET BACKUP_FILE_POSTFIX= CUVIT_SVN 
 
 
rem 타이틀 표시 
@TITLE Backing up subversion databases 
 
rem 백업 파일 이름의 일부로 사용할 문자열 생성 
FOR /F "tokens=1-3 delims=- " %%i IN ('date /t') DO SET DATE=%%i-%%j-%%k 
 
rem 덤프 파일을 생성한다. 
svnadmin dump %REPOSITORY% > SvnDump 
 
rem 압축한다 
SET BACKUP_FILE=%BACKUP_FILE_PREFIX%%DATE%%BACKUP_FILE_POSTFIX%.rar 
"C:\Program Files\WinRAR\rar" a -m5 "%BACKUP_FILE%" SvnDump 
 
rem 덤프 파일을 삭제 
del SvnDump 

dump를 이용한 경우에는, 되돌리려면 svnadmin load 명령을 사용해야 한다.

2 Incremental Backup

• see also Subversion, ConfigurationManagement
  

• CategoryDevelopmentProcess